Subject: Breakout 99 Game Program Start Name

From: "computerclassics2000" <[email-masked]>
Date: Fri, 30 Sep 2011 16:55:12 -0000

I am looking for information on the game name to type in once Bill Parry's BREAKOUT 99 game has been loaded into Mini Memory.

I recently acquired an original cassette version of this program and it loads into Mini Memory from tape without a hitch.

Unfortunately, there are no docs, and I can't seem to guess what name is required at the Mini Memory Program Name prompt.

I have tried GAME, BREAK, BREAKOUT, BREAKOUT99, PARRY and START.

If anyone has the docs and can tell me the Program Name to type in to start the game that would be appreciated.

Alternatively, if you know of some what to figure out what the name is using a programming routine that would be appreciared too.

Thanks!

BillG
09/30/2011

---

From: "Stuart" <[email-masked]>
Date: Fri, 30 Sep 2011 17:31:22 -0000

Load the program, then reset the console, then use MiniMem's EasyBug to peek around the REF/DEF table at the top of the MiniMem RAM - say around >7FF0 onwards. Look for a series of ASCII values that make up a possible name ...

Stuart.

---

From: "Stuart" <[email-masked]>
Date: Fri, 30 Sep 2011 17:33:56 -0000

If you want something a little bit more work, here's a REf/DEF table reader that I wrote yonks ago.

100 REM  
110 REM  SAVE DSK2.RD_REF_TBL  
120 REM  
130 REM  **************   
140 REM  EXTENDED BASIC 
150 REM  **************   
160 REM  REF/DEF TABLE STORED AT TOP OF LOW MEMORY (UP TO >3FFF)  
170 REM  LFAL AT >2004
180 REM  
190 REM  **************** 
200 REM  EDITOR/ASSEMBLER 
210 REM  **************** 
220 REM  REF/DEF TABLE STORED AT TOP OF LOW MEMORY (UP TO >3FFF)
230 REM  LFAL AT >202A
240 REM
250 REM  ******* 
260 REM  MINIMEM 
270 REM  ******* 
280 REM  REF/DEF TABLE STORED AT TOP ON MINIMEM MEMORY (UP TO >7FFF) 
290 REM  LFAM AT >701E 
300 REM  
310 REM  ****************** 
320 REM  GET MODULE TYPE 
330 REM  ****************** 
340 REM  
350 CALL CLEAR
360 PRINT "   --------------------"
370 PRINT "   Ref/Def Table Reader"
380 PRINT "   --------------------"
390 PRINT
400 PRINT "Press:"
410 PRINT
420 PRINT "  1 FOR EXTENDED BASIC"
430 PRINT "  2 FOR EDITOR/ASSEMBLER"
440 PRINT "  3 FOR MINIMEM"
450 CALL KEY(0,K,S)
460 IF S=0 THEN 450
470 IF K<49 THEN 450
480 IF K>51 THEN 450
490 MODULE=K-48
500 REM  
510 REM  ****************** 
520 REM  READ TABLE 
530 REM  ****************** 
540 REM  
550 IF MODULE<>1 THEN 600
560 CALL PEEK(8196,BYTE1,BYTE2)
570 TBL_START=(BYTE1*256)+BYTE2
580 TBL_END=16383
590 GOTO 690
600 IF MODULE<>2 THEN 650
610 CALL PEEK(8234,BYTE1,BYTE2)
620 TBL_START=(BYTE1*256)+BYTE2
630 TBL_END=16383
640 GOTO 690
650 CALL PEEK(28702,BYTE1,BYTE2)
660 TBL_START=(BYTE1*256)+BYTE2
670 TBL_END=32767
680 PRINT
690 FOR LOOP=TBL_START TO TBL_END STEP 8
700 CALL PEEK(LOOP,NAME1,NAME2,NAME3,NAME4,NAME5,NAME6,ADDR1,ADDR2)
710 DECIMAL=LOOP
720 GOSUB 870
730 PRINT HEX$&" ";
740 PRINT CHR$(NAME1)&CHR$(NAME2)&CHR$(NAME3)&CHR$(NAME4)&CHR$(NAME5)&CHR$(NAME6)&" ";
750 DECIMAL=(ADDR1*256)+ADDR2
760 GOSUB 870
770 PRINT HEX$
780 NEXT LOOP
790 END
800 REM  
810 REM  ****************** 
820 REM  SUBROUTINE: 
830 REM  CONVERT DECIMAL TO 
840 REM  HEX 
850 REM  ****************** 
860 REM  
870 HEX$=""
880 MULT=4096
890 DIVIDE=INT(DECIMAL/MULT)
900 IF DIVIDE>9 THEN 930
910 HEX$=HEX$&CHR$(DIVIDE+48)
920 GOTO 940
930 HEX$=HEX$&CHR$(DIVIDE+55)
940 DECIMAL=DECIMAL-(DIVIDE*MULT)
950 MULT=MULT/16
960 IF MULT>=1 THEN 890
970 RETURN

--- In [email-masked], "Stuart" <ti99@...> wrote:
> --- In [email-masked], "computerclassics2000" <computerclassics@> wrote:
> >

---

From: "computerclassics2000" <[email-masked]>
Date: Sat, 01 Oct 2011 03:16:10 -0000

Thanks, Stuart. No luck yet. I did find "CPU", "RESERVED", "COR" and "EASYBUG" between 7FC5 and 7FF2. Tried COR as the name. No luck. Maybe I will key in the BASIC program you were kind enough to share and see if it gives a different perspective.

BillG

---

From: Insane Multitasker <[email-masked]>
Date: Sat, 1 Oct 2011 02:02:28 -0500

I seem to recall Funnelweb listed the program names upon loading an EA3 program, then allowed the user to select.

> To: [email-masked]
> From: [email-masked]
> Date: Sat, 1 Oct 2011 03:16:10 +0000
> Subject: [TI994A] Re: Breakout 99 Game Program Start Name
>

---

From: "Brian Tristam Williams" <[email-masked]>
Date: Sun, 02 Oct 2011 19:37:32 -0000

If that doesn't work, record the cassette audio into your PC and let me have a look at it!

--- In [email-masked], "computerclassics2000" <computerclassics@...> wrote:
> --- In [email-masked], "Stuart" <ti99@> wrote:
> >